Random beta-Polytopes

Expectation of the T-functional, expected intrinstic volumes and expected volume, surface area, mean width and facette number.
(Note: some of these calculations may take an extraordinary amount of time.)

Relevant constants and functions

This slide contains all relevant constants and functions. Please instanciate these before trying to calculate.

Kappa[d_]:=Pi^(d/2)/Gamma[d/2+1]
ExpectSimplex[d_,k_,beta_]:=Factorial[d]^(-k)*(Gamma[(d+1)*(2*beta+k+d)/2+1]/Gamma[(d+1)*(2*beta+d)/2+d*k/2+1])*(Gamma[d/2+beta+1]/Gamma[(d+k)/2+beta+1])^(d+1)*Product[Gamma[(i+k)/2]/Gamma[i/2],{i,1,d}]
ExpectParallel[d_,k_,beta_]:=(Gamma[d/2+beta+1]/Gamma[(d+k)/2+beta+1])^d*Product[Gamma[(d-i+k+1)/2]/Gamma[(d-i+1)/2],{i,1,d}]
ConstC[n_,d_,beta_,b_]:=Binomial[n,d]*Factorial[d]*Kappa[d]*ExpectSimplex[d-1,b+1,beta]*(Pi^(-1/2)*Gamma[d/2+beta+1]/Gamma[(d-1)/2+beta+1])^d
ConstD[n_,d_,beta_,a_,b_]:=If[a==0,Binomial[n,d-1]*(d*Kappa[d]/(2^(n-d+1)*Factorial[d-1]^b))*ExpectParallel[d-1,b+1,beta]*(Pi^(-1/2)*Gamma[d/2+beta+1]/Gamma[(d-1)/2+beta+1])^(d-1),0]
q[d_,b_,beta_]:=d*beta+(d-1)*(d+b+1)/2
const[d_,b_]:=Gamma[d/2+b+1]/(Pi^(d/2)*Gamma[b+1])
F[d_,beta_,h_]:=const[1,beta+(d-1)/2]*Integrate[(1-t^2)^(beta+(d-1)/2),{t,-1,h}]
gam[d_,k_]:=Binomial[d,k]*Kappa[d]/(Kappa[d-k]*Kappa[k])
TfuncP[n_,d_,beta_,a_,b_]:=ConstC[n,d,beta,b]*Integrate[Abs[h]^a*(1-h^2)^(q[d,b,beta])*F[d,beta,h]^(n-d),{h,-1,1}]
TfuncS[n_,d_,beta_,a_,b_]:=2^d*ConstC[n,d,beta,b]*Integrate[h^a*(1-h^2)^(q[d,b,beta])*(F[d,beta,h]-F[d,beta,-h])^(n-d),{h,0,1}]
TfuncQ[n_,d_,beta_,a_,b_]:=ConstD[n,d,beta,a,b]+ConstC[n,d,beta,b]*Integrate[h^a*(1-h^2)^(q[d,b,beta])*F[d,beta,h]^(n-d),{h,0,1}]
VolP[n_,d_,beta_]:=(Kappa[d]/((d+1)*Kappa[d+1]))*TfuncP[n,d+1,beta-1/2,0,1]
VolS[n_,d_,beta_]:=(Kappa[d]/((d+1)*Kappa[d+1]))*TfuncS[n,d+1,beta-1/2,0,1]
VolQ[n_,d_,beta_]:=(Kappa[d]/((d+1)*Kappa[d+1]))*TfuncQ[n,d+1,beta-1/2,0,1]
IntrinsicVolP[n_,d_,k_,beta_]:=gam[d,k]*VolP[n,k,beta+(d-k)/2]
IntrinsicVolS[n_,d_,k_,beta_]:=gam[d,k]*VolS[n,k,beta+(d-k)/2]
IntrinsicVolQ[n_,d_,k_,beta_]:=gam[d,k]*VolQ[n,k,beta+(d-k)/2]
SurfP[n_,d_,beta_]:=2*IntrinsicVolP[n,d,d-1,beta]
SurfS[n_,d_,beta_]:=2*IntrinsicVolS[n,d,d-1,beta]
SurfQ[n_,d_,beta_]:=2*IntrinsicVolQ[n,d,d-1,beta]
WidthP[n_,d_,beta_]:=IntrinsicVolP[n,d,1,beta]/gam[d,1]
WidthS[n_,d_,beta_]:=IntrinsicVolS[n,d,1,beta]/gam[d,1]
WidthQ[n_,d_,beta_]:=IntrinsicVolQ[n,d,1,beta]/gam[d,1]
FacetteP[n_,d_,beta_]:=TfuncP[n,d,beta,0,0]
FacetteS[n_,d_,beta_]:=TfuncS[n,d,beta,0,0]
FacetteQ[n_,d_,beta_]:=TfuncQ[n,d,beta,0,0]

Calculation sheet

Enter dimension (d), number of points (n) and parameter of the distribution (beta)

d=2;
n=3;
beta=0;

The polytope P (convex hull of the points):

Expected volume, surface area, mean width and facette number:

VolP[n,d,beta]

SurfP[n,d,beta]

WidthP[n,d,beta]

FacetteP[n,d,beta]

Expected k - th intrinic volume (enter an additional parameter k):

k=1;

IntrinsicVolP[n,d,k,beta]

Expected value of the T - Functional (enter two additional parameters a, b) :

a=0;
b=1;

TfuncP[n,d,beta,a,b]

The polytope S (absolute convex hull of the points):

Expected volume, surface area, mean width and facette number:

VolS[n,d,beta]

SurfS[n,d,beta]

WidthS[n,d,beta]

FacetteS[n,d,beta]

Expected k - th intrinic volume (enter an additional parameter k):

k=1;

IntrinsicVolS[n,d,k,beta]

Expected value of the T - Functional (enter two additional parameters a, b) :

a=0;
b=1;

TfuncS[n,d,beta,a,b]

The polytope Q (convex hull of the points and the origin):

Expected volume, surface area, mean width and facette number:

VolQ[n,d,beta]

SurfQ[n,d,beta]

WidthQ[n,d,beta]

FacetteQ[n,d,beta]

Expected k - th intrinic volume (enter an additional parameter k):

k=1;

IntrinsicVolQ[n,d,k,beta]

Expected value of the T - Functional (enter two additional parameters a, b) :

a=0;
b=1;

TfuncQ[n,d,beta,a,b]